ODS LAYOUTによるワクチンの臨床開発におけるDashboard …– ods layout start ; ~ ods...

SASユーザー総会 2013

ODS LAYOUTによるワクチンの臨床開発におけるDashboardの作成

武田薬品工業株式会社高浪洋平


2

今日のお話

1.DashboardとODS LAYOUTの概要

Dashboardの概要

ODS LAYOUTの概要

2. ワクチンの臨床開発におけるDashboardの作成

ワクチンの臨床開発の概要

ワクチンの臨床開発におけるDashboardの作成

3. おわりに


3

今日のお話


Dashboardの概要

ODS LAYOUTの概要




3. おわりに


はじめに

発表の動機

– 薬剤開発において製薬企業が意思決定を行う際は、臨床試験における有効性・安全性プロファイルが解析結果の数百・数千ページにまたがって散在していて、それらから必要な情報を抜き出して分析する必要があり、かなりの労力・時間を要する作業となる。

– 臨床試験においても、開発中の薬剤の有効性及び安全性プロファイルが1画面（または1ページ）にまとめられていれば、意思決定を行う際の有用なツールとなり得ると考え、作成を試みた。

4


Dashboard（ダッシュボード）の概要 Dashboardとは

– 1画面（または1ページ）に重要かつ必要な情報・指標を整理して表示したもの

– 自動車のダッシュボードも同じ言葉

5


ODS LAYOUTの概要 ODS LAYOUT

– 解析結果の要約表やグラフのレイアウトをカスタマイズする機能

• 簡易Dashboardを作成することが可能

• SASⓇ9.3のODS PDFとの相性が良い（RTFでは正しく出力されない場合がある）

ODS LAYOUTの構文

– ods layout start ; ~ ods layout end ;の間にods region ;を記述して各レポート・グラフを作成する。

6

ods layout start <option> ; ods region ; <レポート出力プログラム> ods region ; <レポート出力プログラム> ... ods layout end ;


ODS LAYOUTの概要

ODS LAYOUTの使用方法

– ①グリッドを定義する方法

• columns,rowsオプションで1ページのレポート数を指定

• 複数ページにまたがる場合に制御し易い

• グリッドの順番に出力されるので指定が簡単！

– ②グリッドを定義しない方法（出力位置・サイズを定義する方法）

• 全体及び個々の出力領域のサイズと位置を指定

• 各出力領域を個別に指定する必要があるので調整が難しい

• 自由にレイアウトをカスタマイズできる

• 使用例：ods layout start width=7.5in height=11.5in

7


ODS LAYOUTのオプション ODS LAYOUTとODS REGIONのオプション

– ODS LAYOUTステートメントのオプション

– ODS REGIONステートメントのオプション

8

オプション内容

rows=x, columns=y 行、列のグリッド数を指定

width=x, height=y レイアウト領域の幅と高さを指定

row_gutter=x, column_gutter=y 行、列のグリッド間のスペースを指定

row_heights=(x y z), column_widths=(x y z) 各グリッドの幅と高さをまとめて指定

オプション内容

width=x, height=y 該当する領域の幅と高さを指定

x=x, y=y 出力位置（座標）を指定

row_span=x, column_span=y 行、列のグリッドの結合数を指定

row=x, column=y 該当するグリッドを指定


ODS LAYOUT（グリッドの定義） ODS LAYOUTの使用方法（グリッドを定義する方法）


– columnsとrowsで1ページあたりの出力数を定義する。

9

ods layout start columns=2 rows=2 column_gutter=0.1in row_gutter=0.1in ; ods region ; <レポート出力プログラム1> ods region ; <レポート出力プログラム2> ... ods layout end ;



– columns=2,rows=2で1ページあたり4個のレポート・グラフを作成する。

10

ods layout start columns=2 rows=2 ;

Report 1 Report 2

Report 3 Report 4



– columns=2,rows=2で1ページあたり4個の領域を定義

– column_widths, row_heightsオプションで各領域の幅・高さを定義

– column_spanオプションで3行目は1つの領域として定義

– column_gutter, row_gutterオプションで領域間のスペースを定義

11

ods layout start columns = 2 rows = 2 column_gutter = 0.1in row_gutter = 0.1in column_widths = (5in 3in) row_heights = (5in 5in) ; ods region ; <レポート出力プログラム> ods region ; <レポート出力プログラム> ods region column_span=2 ; <レポート出力プログラム> ods layout end ;



12

Report 1 row 1

column 1

Report 2 row 1

column 2

Report 3 row 2

column 1 and 2

columns=2 rows=2

5in

5in

5in 3in

column_span=2

row_heights=(5in 5in)

column_widths=(5in 3in)


ODS LAYOUT（グリッドの定義） ODS LAYOUTの使用例①

– 自動車の企業別・タイプ別の平均価格のレポートの作成（地域ごとのグラフと要約表）

– SASHELPライブラリのCARSデータセットを使用

13

Graph 1 (Asia)

Graph 2 (USA)

Graph 3 (Europe)

Table (All regions)



– columns=2,rows=2で1ページあたり4個のグリッドを定義

– ods regionの後にsgpanelプロシジャで棒グラフを作成

– 同様に棒グラフを合計3個作成

14

ods graphics on / width=3.8in height=5in ; ods pdf style=Statistical ; ods layout start columns=2 rows=2 column_gutter=0.1in row_gutter=0.1in ; *--- グリッドの定義 ; ods region ; *--- 1個目のグリッド ; title "Asia" ; proc sgpanel data=sashelp.cars ; *--- 1個目のグラフ ; where ORIGIN="Asia" ; panelby TYPE / layout=panel rows=3 columns=2 novarname ; vbar MAKE / response=MSRP group=MAKE stat=mean dataskin=sheen ; keylegend / title="Companies/Brands" ; colaxis display=(nolabel novalues noticks) ; label MSRP='Average ($)' ; format MSRP 8. ; run ;



– 最後の表作成とods layout end ;でレポートを出力

15

ods region ; *--- 4個目のグリッド ; title "Average price by Type and Region" ; proc tabulate data=sashelp.cars ; *--- 4個目のグリッドの表 ; class ORIGIN TYPE MAKE ; var MSRP ; table TYPE="",ORIGIN*MSRP=""*(n*f=best. mean*f=dollar10.) / row=float ; run ; title ; ods layout end ; *--- レイアウトの終了処理 ; ods pdf close ;



– 自動車の企業別・タイプ別の平均価格のレポートの作成（地域ごとのグラフと要約表）

16

Graph 1 (Asia)

Graph 3 (Europe)

Graph 1 (USA)

Table (All regions)


ODS LAYOUT（出力位置・サイズの定義） ODS LAYOUTの使用方法（出力位置・サイズを定義する方法）

– 個別に出力サイズ・位置を指定


– widthとheightで1ページの出力領域（サイズ）を定義する。

– ods regionでは、widthとheightで各グラフ・表の出力領域、xとyで開始位置を指定する。

17

ods layout start width=8in height=11in ; ods region width=3in height=3in x=0.5in y=1in ; <表・グラフ出力プログラム1> ods region width=3in height=3in x=4.5in y=4.5in ; <表・グラフ出力プログラム2> ods layout end ;


LAYOUT(11in x 8in)

ODS LAYOUT（出力位置・サイズの定義） ODS LAYOUTの使用方法（出力位置・サイズを定義する方法）

– 2つのレポート領域を定義する。

18

ods layout start width=8in height=11in ; ods region width=3in height=3in x=0.5in y=1in ; ods region width=3in height=3in x=4.5in y=4.5in ;

Report 2 (3in x 3in)

Report 1 (3in x 3in)


LAYOUT(11in x 8in)

ODS LAYOUT（出力位置・サイズの定義） ODS LAYOUTの使用例②

– 自動車のタイプ別の平均燃費(MPG)の都市部・高速道路の棒グラフ

• MPG: Mile per gallon

• 1 gallon = 3.78541178 L

19

ods layout start width=8in height=11in ; ods region width=5in height=4in x=0.5in y=1in ; ods region width=5in height=4in x=2in y=6in ;

Graph 2 MPG (Highway)

(4in x 5in)

Graph 1 MPG (City) (4in x 5in)




– 1個目のグラフとods textによるテキスト出力

20

title j=c h=12pt "MPG for all region and companies" ; ods graphics on / width=4.5in height=3.8in ; ods pdf style=Statistical ; ods layout start width=8in height=11in ; ods region width=5in height=4in x=0.5in y=1in ; title "MPG(City) by Type" ; proc sgplot data=sashelp.cars ; vbar TYPE / response=MPG_City group=TYPE stat=mean dataskin=sheen datalabel ; format MPG_City 8.1 ; run ; title ; ods text="MPG (City) of Hybrid is the highest one in all types." ;




– 2個目のグラフとods textによるテキスト出力

– ods layout end ;でレポート出力

21

ods region width=5in height=4in x=2in y=6in ; title "MPG(Highway) by Type" ; proc sgplot data=sashelp.cars ; vbar TYPE / response=MPG_Highway group=TYPE stat=mean dataskin=sheen datalabel ; format MPG_Highway 8.1 ; run ; title ; ods text="MPG (Highway) of Hybrid is the highest one in all types." ; ods layout end ; ods pdf close ;



– 自動車のタイプ別の平均燃費(MPG)の都市部・高速道路のグラフ

22

Graph 1 MPG (City)

Graph 2 MPG (Highway)

Text

Title


23

今日のお話


Dashboardの概要

ODS LAYOUTの概要




3. おわりに


ワクチンの臨床開発ワクチンとは

– ワクチンとは、病原体あるいは細菌毒素の毒性を弱めたり失わせたりしたものを人為的に接種しておくことで、人間が本来持っている「病原体に対する抵抗力（免疫）」のシステムを利用して、これらのさまざまな感染症に対する「免疫」をあらかじめ作らせておく製剤であり、発病することなく免疫反応の記憶を残すことが可能となる（http://www.takeda.co.jp/）。

ワクチンの臨床開発（国内外のガイドライン） – 感染症予防ワクチンの臨床試験ガイドライン(薬食審査発 0527 第 5

号, 2010/5)

– Guidelines on clinical evaluation of vaccines:regulatory expectations (WHO Technical Report, Series No. 924, 2004)

– GUIDELINE ON CLINICAL EVALUATION OF NEW VACCINES(EMEA/CHMP/VWP/164653/2005)

24

http://www.takeda.co.jp/�


ワクチンの臨床開発ワクチンの臨床開発の概要

– 生活習慣病治療薬等の通常の薬剤開発との比較

25

分類ワクチン通常の薬剤

目的感染症予防疾患の治療

対象健常人患者

薬物動態試験通常実施しない実施する

症例数感染防御等のワクチン有効性を評価する場合は数千～数万例

数百～数千例（ハードエンドポイントの場合は数千～万例）

有効性の評価等・サロゲートとなる抗体価等の免疫原性の評価・感染防御については、他の薬剤の普及により感染症感染率が激減し、評価が困難となる。・プラセボの使用は困難

・サロゲートとなる臨床検査項目の評価・心血管イベント等については、多数の症例が必要となるが、患者は多数存在する。・プラセボの使用は可能

併用薬・併用治療同時接種、混合ワクチン併用薬、併用治療、配合剤

その他・ロット間の比較・アジュバント、ブースター、株・オブザーバーブラインド（プラセボ作成が困難な状況）

左記については、臨床試験では通常主な評価の対象とはならない


ワクチンの臨床開発ワクチンの臨床開発の概要

– ワクチンの臨床開発における主な評価項目

– 解析手法の概要や解説に関しては松尾、甘利、大橋（2010）やJozef Nauta（2010）をご参照ください。

26

分類評価項目備考

有効性幾何平均抗体価（GMT）幾何平均比（GMR）

抗体価は抗原抗体反応より得られる指標で、通常、ワクチンの抗体価については対数正規性を仮定（投与群間の比較はGMR）

逆累積分布曲線抗体価の分布を図示

抗体保有率、抗体陽転率抗体保有の基準を満たす被験者の割合

ワクチン有効性（VE）大規模臨床試験による感染防御等の評価

安全性有害事象通常の薬剤開発と同様

局所反応・全身反応日誌等による接種後の局所・全身反応


ワクチン開発におけるDashboard ワクチンの臨床開発におけるDashboardの提案

– 今回想定する架空の臨床試験

27

項目内容

相第III相検証試験（試験名：PROD-XXX/STUDY-XXX）

対象健康乳幼児

試験デザイン 2群（被験薬群（Vaccine A）・対照薬群（Vaccine B））並行群間無作為化比較試験初回免疫期として皮下に3回接種、追加免疫期として皮下に1回接種

目的被験薬と既承認ワクチンとの非劣性を検証する。

主要評価項目初回免疫期3回接種後の抗体保有率（対照薬群との非劣性検定）

その他の評価項目抗体価のGMT、逆累積分布曲線、有害事象、局所反応・全身反応の発現率


ワクチン開発におけるDashboard ワクチンの臨床開発におけるDashboardの提案

– 今回想定する架空の臨床試験

28

初回免疫期

1回目接種

• 接種前抗体価測定

• 日誌データ（局所・全身）

初回免疫期

2回目接種


初回免疫期

3回目接種

• 接種1カ月後に抗体価測定


追加免疫期

• 接種前および接種1ヵ月後に抗体価測定



ワクチン開発におけるDashboard ワクチン開発の臨床試験におけるテストデータ

– IDと投与群の情報を格納したデータセット：_MASTER

29



– 各評価時点の抗体価(_TITER)、対数変換後の抗体価(LOG_TIT)、抗体保有の有無(_SERO)を格納したデータセット：_TITER

30



– 各接種後の各投与群別の局所・全身反応の発現率を格納したデータセット：_LR_T, _SR_T

• あらかじめ各投与群の発現率を計算しておく。

• _G1: Vaccine Aの発現率、_G2：Vaccine Bの発現率

31



– 有害事象データ：_AE

– 器官別大分類(_SOC)、基本語(_PT)を格納

32


ワクチン開発におけるDashboard SASによる各評価項目の解析方法と表・グラフの作成方法

– Dashboardに出力する評価項目とSASによる解析方法及び表・グラフの作成方法

33

分類評価項目 SASによる解析

有効性幾何平均抗体価（GMT） SGPANELプロシジャによるヒストグラム・フォレストプロット・箱ひげ図の作成

逆累積分布曲線 SGPANELのSTEPステートメントによる逆累積分布曲線の作成

抗体保有率・SGPLOTプロシジャによる棒グラフ・FREQプロシジャによる非劣性検定の実行

安全性有害事象の発現率有害事象のリスク比

・SGPLOTプロシジャによる発現率の棒グラフ・GTLとSGRENDERプロシジャによる発現率とリスク比のプロットの作成

局所反応・全身反応 SGPLOTプロシジャによる発現率の棒グラフの作成


ワクチン開発におけるDashboard 逆累積分布曲線の作成

– FREQプロシジャで時点・薬剤ごとに累積パーセントを算出

– 累積パーセントを100から引いて逆累積パーセントを算出

– SGPANELプロシジャのSTEPステートメントで逆累積分布曲線を作成

34

proc sort data=_TITER ; by VISIT _GRP ; run ; ods listing close ; ods output Onewayfreqs=_OUTFREQ(keep =VISIT _GRP LOG_TIT cumpercent) ; proc freq data=_TITER ; by VISIT _GRP ; table LOG_TIT ; run ; ods output close ; ods listing ; data _RCD ; set _OUTFREQ ; by VISIT _GRP ; if first._GRP then do ; _CDF = 100 ; output ; end ; _CDF = 100-cumpercent ; *--- 逆累積パーセント ; output ; run ;


ワクチン開発におけるDashboard 逆累積分布曲線の作成

– FREQプロシジャで時点・薬剤ごとに累積パーセントを算出

– 累積パーセントを100から引いて逆累積パーセントを算出

– SGPANELプロシジャのSTEPステートメントで逆累積分布曲線を作成

35

proc sgpanel data=_RCD ; where VISIT in(10,20) ; panelby VISIT / novarname ; step x=LOG_TIT y=_CDF / group=_GRP justify=right legendlabel="" ; keylegend / title="" ; rowaxis integer label='Percent (%)'; colaxis integer display=(nolabel) ; run ;

抗体価が高く（右側に寄っている）、勾配が急な曲線であれば良好な免疫原生を有するワクチン


ワクチン開発におけるDashboard ヒストグラムの作成

– SGPANELプロシジャのHISTOGRAMステートメントでワクチン接種後の抗体価のヒストグラムを作成

36

proc sgpanel data=_TITER noautolegend ; where VISIT=20 ; panelby _GRP / layout=columnlattice novarname ; histogram LOG_TIT / scale=count fillattrs=(color=salmon) transparency=0.5 ; density LOG_TIT / type=normal legendlabel="" ; rowaxis label="Count" ; colaxis label="Log-Titer after priming vaccination" ; run ;


ワクチン開発におけるDashboard 抗体保有率の棒グラフの作成

– SGPLOTプロシジャのVBARステートメントで棒グラフを作成

37

proc sgplot data=_SRATE noautolegend ; where _SERO = 1 ; vbar VISIT / response=RowPercent barwidth=1.0 group=_GRP datalabel dataskin=sheen groupdisplay=cluster ; yaxis label='Percent(%)' ; xaxis display=(nolabel) ; format RowPercent 6.1 ; run ;

ワクチン接種後は感染防御のための高い抗体保有率が求められる。


ワクチン開発におけるDashboard 箱ひげ図の作成

– SGPANELプロシジャのHBOXステートメントで箱ひげ図を作成

38

proc sgpanel data=_TITER ; where VISIT in(10,20) ; panelby VISIT / layout=columnlattice novarname ; hbox LOG_TIT / group=_GRP boxwidth=0.5 legendlabel="" grouporder=ascending groupdisplay=cluster ; keylegend / title=" " ; colaxis integer label='Log-Titer' ; run ;


ワクチン開発におけるDashboard GMTのフォレストプロットの作成

– 事前にGMT、信頼区間の上限・下限を算出し、SGPANELプロシジャのSCATTERステートメントで各変数を指定する。

39

proc summary data=_TITER missing noprint nway alpha=0.05 ; class VISIT _GRP ; var LOG_TIT ; output out=_LOG(drop=_TYPE_ _FREQ_) mean=_GMT stddev=_GSD lclm=_LCLM uclm=_UCLM ; run ; data _LOG_BACK ; set _LOG ; GMT = exp(_GMT) ; GM_SD = exp(_GSD) ; UCLM = exp(_UCLM) ; LCLM = exp(_LCLM) ; GMTSD_C = strip(put(GMT,7.1))||" ("||strip(put(GM_SD,7.2))||")" ; UCLM_C = strip(put(UCLM,7.2)) ; LCLM_C = strip(put(LCLM,7.2)) ; *--- For using markerchar option in scatter plot ; X1 = "GMT(SD)" ; X2 = " LCL" ; X3 = " UCL" ; run ;

逆対数変換

文字をグラフに出力するための細工


ワクチン開発におけるDashboard GMTのフォレストプロットの作成

– 事前にGMT、信頼区間の上限・下限を算出し、SGPANELプロシジャのSCATTERステートメントで各変数を指定する。

40

proc sgplot data=_LOG_BACK noautolegend ; where VISIT = 20 ; scatter x=GMT y=_GRP / xerrorlower=LCLM xerrorupper=UCLM markerattrs=(color=black symbol=circlefilled) ; scatter x=x1 y=_GRP / x2axis markerchar=GMTSD_C ; scatter x=x2 y=_GRP / x2axis markerchar=LCLM_C ; scatter x=x3 y=_GRP / x2axis markerchar=UCLM_C ; refline 750 / axis=x lineattrs=(pattern=1) ; yaxis discreteorder=unformatted integer display=(nolabel) offsetmin=0.3 offsetmax=0.3 ; xaxis offsetmin=0.1 offsetmax=0.5 label="GMT and 95% CI after priming vaccination" ; x2axis display=(noticks nolabel) offsetmin=0.65 offsetmax=0.05 ; format GMT 7.1 GM_SD UCLM LCLM 7.2 ; run ;

markercharでグラフに文字列を出力

グラフと文字出力部分の調整


ワクチン開発におけるDashboard 抗体保有率の非劣性検定の実行

– FREQプロシジャのriskdiffオプションでFarrington and Manning（1990）の非劣性検定を実行

41

ods output CrossTabFreqs=_SRATE (where=(_TYPE_="111")) ; ods output PdiffNoninf=_FM ; proc freq data=_TITER ; table VISIT*_GRP*_SERO / nocol nopercent riskdiff(method=FM noninf margin=0.1) ; run ; ods output close ; data _FM2 ; set _FM ; if _N_ = 2 ; run ; proc print data=_FM2 label noobs style(header)={background=Azure} ; var Estimate Pvalue / style={width=100pt} ; label Pvalue = "P-value of Non-inferiority Test" ; run ;

noninf, margin, methodで非劣性検定を実行


ワクチン開発におけるDashboard 有害事象の発現率

– あらかじめ各投与群の有害事象の発現率を計算し、下記のデータセットを作成し、SGPLOTプロシジャで棒グラフを重ね合わせて出力する（高浪（2012））

42

各群の発現例数各群の発現率 PT


ワクチン開発におけるDashboard 有害事象の発現率

– あらかじめ各投与群の有害事象の発現率を計算し、下記のデータセットを作成し、SGPLOTプロシジャで棒グラフを重ね合わせて出力する（高浪（2012））

43

*--- 発現率の棒グラフの作成 ; ods graphics on / width=3in height=2.8in ; title 'Incidence Rate (%) of Adverse Events' ; proc sgplot data=_OUT ; where _PAGE = 1 ; hbar _PT / response=_P1 barwidth=0.5 fillattrs=(color=blue) dataskin=sheen name="G1" ; *--- 群1 ; hbar _PT / response=_P2 barwidth=0.8 fillattrs=(color=salmon) dataskin=sheen name="G2" transparency=0.5 ; *--- 群2 ; keylegend "G1" "G2" ; yaxis discreteorder=DATA display=(nolabel) ; xaxis values=(0 to &_MAXP by 5) label='Incidence Rate (%)' ; run ; title ;

群2を半透明にする


ワクチン開発におけるDashboard 有害事象の発現率・リスク比プロットの作成

– GTLで発現率・リスク比のプロットを作成(高浪・舟尾(2012)、高浪(2012))

44

proc template ; define statgraph _AEPCTRR ; dynamic VAR1 VAR2 AE_NAME EST LOWER UPPER TITLE ; begingraph ; entrytitle TITLE ; layout lattice / columns=2 rows=1 columngutter=3px columnweights=(.5 .5) rowdatarange=unionall ; rowaxes ; rowaxis / label=" " ; endrowaxes ; *--- 横軸の定義 ; columnaxes ; columnaxis / label=" " ; endcolumnaxes ; *--- 縦軸の定義 ; layout overlay / xaxisopts = (linearopts=(tickvaluesequence=(start=0 end=&_MAXP increment=5) tickvaluepriority=true)) yaxisopts = (display=(line ticks tickvalues)) ; referenceline y=AE_NAME / lineattrs=(color=lightgray pattern=2) ; scatterplot x=VAR1 y=AE_NAME / markerattrs=(symbol=trianglefilled) name="T1" legendlabel="Vac.A" ; scatterplot x=VAR2 y=AE_NAME / markerattrs=(symbol=square) name="T2" legendlabel="Vac.B" ; endlayout ; layout overlay / xaxisopts = (type=log logopts=(base=2 tickintervalstyle=logexponent)) ; referenceline x=1 / lineattrs=(color=lightgray pattern=1) ; referenceline y=AE_NAME / lineattrs=(color=lightgray pattern=2) ; scatterplot x=EST y=AE_NAME / xerrorlower = LOWER xerrorupper = UPPER errorbarattrs = (pattern=1 color=darkred) markerattrs = (color=black symbol=circlefilled) ; endlayout ; sidebar / align=bottom ; discretelegend "T1" "T2" / border=false displayclipped=true ; endsidebar; endlayout ; endgraph ; end ; run ;

左側に発現率、右側にリスク比のプロット


ワクチン開発におけるDashboard 有害事象の発現率、リスク比プロットの作成

– GTLで発現率・リスク比のプロットを作成(高浪・舟尾(2012)、高浪(2012))

45

ods region ; ods graphics on / width=3in height=3in ; ods text=" ¥n " ; proc sgrender data=_PCTRR2 template=_AEPCTRR ; where _PAGE = 1 ; label _P1="Pct." Value='RR' ; dynamic VAR1="_P1" VAR2="_P2" AE_NAME="_PT" EST="Value" LOWER="LowerCL" UPPER="UpperCL" TITLE="Incidence Rate (%) and RR (Base=2)" ; run ;

リスク比と信頼区間を算出してデータセットに格納しておき、templateを指定する。Dynamic変数についてもここで指定する。

Value：リスク比 LowerCL：信頼下限 UpperCL：信頼上限


ワクチン開発におけるDashboard 局所反応・全身反応の発現率グラフの作成

– SGPLOTプロシジャのVBARステートメントで棒グラフの重ね合わせを作成（論文集の付録参照）

46


ワクチン開発におけるDashboard コメント、画像の出力

– ODS TEXTステートメントでコメントを出力

– postimageオプションで画像ファイルを指定して出力

47

ods text="¥S={fontfamily='Arial' just=l postimage='./ワクチン.png'} ¥n¥nSeroprotection Rate of Vaccine A after priming vaccination period and booster period was slightly higher than that of Vaccine B. ¥n " ;

ods text="¥S={fontfamily='Arial' just=l postimage='./ワクチン2.png'} ¥n¥nIncidence rate of Adverse Events are almost the same between treatment groups. ¥n " ;


ワクチン開発におけるDashboard Dashboardのレイアウト

– グリッドを定義（上段：有効性、下段：安全性）

48

逆累積分布曲線抗体保有率の棒グラフ

有害事象の発現率棒グラフ

有効性

抗体価の箱ひげ図

有害事象のリスク比プロット

抗体価のヒストグラム

（ワクチン接種後）

GMTのプロット非劣性検定結果コメント

コメント

局所反応・全身反応の

棒グラフ安全性コメント



– 3行5列

– 一部ods regionでcolumn_spanを使用して領域を結合

49

ods layout start columns = 5 rows = 3 column_gutter = 0.1in row_gutter = 0.1in column_widths = (3in 3in 1.5in 1.5in 1.5in) row_heights = (2.5in 1.2in 3.5in) ;

各行・列の幅と高さを指定

各行・列のグリッド数を指定



– 3行5列（一部ods regionでcolumn_spanを使用して複数領域を結合）

50

columns=5 rows=3

2.5in

3.5in

3in 1.5in

逆累積分布曲線抗体保有率の棒グラフ

有害事象の発現率棒グラフ

抗体価の箱ひげ図

有害事象のリスク比プロット

抗体価のヒストグラム

（ワクチン接種後）

GMTのプロット非劣性検定結果コメント

コメント

局所反応・全身反応の

棒グラフコメント

1.2in

3in 1.5in 1.5in


ワクチン開発におけるDashboard TEMPLATEプロシジャによるスタイル定義

51

proc template ; define style Mystat ; parent=styles.statistical ; class container / backgroundcolor = white fontfamily="Times New Roman" fontsize=9pt ; *--- ods text部分に効く ; class document / backgroundcolor = white ; class body / backgroundcolor = white leftmargin=0.5cm rightmargin=0.5cm topmargin=0.5cm bottommargin=0.5cm ; class table / backgroundcolor = CXFFFACD frame=box rules=rows bordercolor=black ; class cell / backgroundcolor = white ; class data / backgroundcolor = white fontfamily="Times New Roman" fontsize=8pt ; *--- 表中の数値に効く ; class output / backgroundcolor = white ; class RowHeader / backgroundcolor = CXFFFACD fontfamily="Times New Roman" fontsize=8pt ; class Header / backgroundcolor = CXFFFACD fontfamily="Times New Roman" fontsize=8pt ; class GraphBackground / color = Azure ; *--- グラフ軸の外側の背景色 ; class GraphWalls / color = white frameborder = on linestyle = 1 linethickness = 1px ; *--- グラフ背景 ; class GraphBorderLines / contrastcolor = black linestyle = 1 linethickness = 1px ; *--- 外側のライン ; class GraphAxisLines / contrastcolor = black linestyle = 1 linethickness = 1px tickdisplay = "outside" ; *--- 軸線の定義 ; class GraphdataDefault / contrastcolor = blue linestyle = 1 linethickness = 1px markersymbol = "circlefilled" foreground = blue ; class Graphdata1 / contrastcolor = blue linestyle = 2 linethickness = 1px markersymbol = "trianglefilled" foreground = CX696969 ; class Graphdata2 / contrastcolor = red linestyle = 1 linethickness = 1px markersymbol = "circlefilled" foreground = lightgray ; end ; run ;

グラフの出力スタイルを定義

文書全体のスタイルを定義

表の出力スタイルを定義


ワクチン開発におけるDashboard Dashboard作成プログラムの処理フロー（詳細は論文集参照）

52

• スタイルの定義（TEMPLATEプロシジャ）

• 抗体保有率の算出、非劣性検定の実行 • 累積パーセントの算出、GMTの算出

• ODF PDF、ODS LAYOUTの開始

• グリッドの定義

• ODF REGIONと各評価項目の出力

• ODF PDF、ODS LAYOUTの終了処理


ワクチン開発におけるDashboard ダッシュボードの出力（PDF形式）

53


54

今日のお話


Dashboardの概要

ODS LAYOUTの概要




3. おわりに


おわりに

ODS LAYOUTによるダッシュボードの作成

– Dashboardは意思決定において重要なツールとなり得る。

– ODS LAYOUTを使用することでレポートの出力レイアウトを比較的自由にカスタマイズし、簡易Dashboardを作成することが可能。

ワクチン開発における活用事例

– ワクチンの臨床試験において求められる主な有効性・安全性のプロファイルを要約したDashboardの作成方法を提案した。

今後の展開

– 薬剤・疾患領域によって出力内容が異なっていても、SASによる表やグラフの基本的な作成方法は同じであるため、ワクチン開発のみならず、他の疾患領域にも応用が可能である。

– 出力する内容をあらかじめ標準化しておくことによって、ある程度のマクロ化は可能。SASのバージョンアップによる更なる機能向上にも期待したい。

55


参考文献 Dan O'Connor & Scott Huntley, SAS Institute, Inc. Custom Reporting Using

ODS Layout. SAS Global Forum 2008

感染症予防ワクチンの臨床試験ガイドライン(薬食審査発 0527 第 5 号, 2010)

Guidelines on clinical evaluation of vaccines: regulatory expectations (WHO Technical Report, Series No. 924, 2004)

GUIDELINE ON CLINICAL EVALUATION OF NEW VACCINES(EMEA/CHMP/VWP/164653/2005)

Jozef Nauta. Statistics in Clinical Vaccine Trials. Springer (2010)

松尾富士男、甘利裕邦、大橋靖雄（2010）「ワクチンの評価における統計解析」臨床と微生物 Vol.37 No.3

Farrington, C.P. and G. Manning, 1990. Test statistics and sample size formulae for comparative binomial trials with null hypothesis of nonzero risk difference or nonentity relative risk. Stat. Med., 9: 1447-1454. DOI: 10.1002/sim.4780091208

高浪洋平、舟尾暢男（2012）「統計解析ソフト『SAS』」（工学社）」

高浪洋平（2011）「SGプロシジャとGTLによるグラフの作成とODS PDFによる統合解析帳票の作成～TQT試験における活用事例～」SASユーザー総会2011

高浪洋平（2012）「SASとHTMLアプリケーションによるCDISC ADaM形式の解析用データセットを用いた有害事象の解析帳票・グラフ簡易作成ツールの開発事例」SASユーザー総会2012

56


ご清聴ありがとうございました

57

ODS LAYOUTによるワクチンの臨床開発におけるDashboard …– ods layout start ; ~ ods...

Documents

Transcript of ODS LAYOUTによるワクチンの臨床開発におけるDashboard …– ods layout start ; ~ ods...

ODS LAYOUTによる ワクチンの臨床開発におけるDashboard …– ods layout start ; ~ ods...

Documents

Transcript of ODS LAYOUTによる ワクチンの臨床開発におけるDashboard …– ods layout start ; ~ ods...

ODS LAYOUTによるワクチンの臨床開発におけるDashboard …– ods layout start ; ~ ods...

Transcript of ODS LAYOUTによるワクチンの臨床開発におけるDashboard …– ods layout start ; ~ ods...